Auto-DJ

L'auto-dj est le “logiciel” qui définit la diffusion de la musique pendant tous les “trous” de la grille (lorsqu'aucune émission, en direct ou pré-enregistrée, n'est diffusée).

Notre auto-dj est construit avec bout de script Liquidsoap qui est inséré au milieu du script Liquidsoap de libretime. Un deuxième script Liquidsoap est nécessaire afin de récupérer en entrée un flux audio `http` provenant de Libretime pour le fournir en sortie sur la carte son de l'ordinateur (en direction de la table de mixage).

Ce deuxième script est nécessaire car Libretime est lancé en tant que “daemon system” et dans ce cas n'a pas pas les bons droits pour accéder correctement à la carte son. Le deuxième script liquidsoap est donc lancé lui en tant que “daemon user” afin de pouvoir envoyer le flux correctement sur la carte son. Cette configuration est un bidouillage qui pallie à un défaut de Libretime.

Sript Liquidsoap dans Libretime

Le script liquidsoap inséré dans Libretime est documenté via des commentaires au sein même du script pour expliquer le fonctionnement de chaque section.

Le script en question est le fichier `ls_script.liq` situé dans `/opt/libretime/lib/python3.8/site-packages/libretime_playout/liquidsoap/1.4/ls_script.liq`.

Extrait inséré dans le script Liquidsoap - màj 10/01/2025 (cliquer pour afficher le script)

extrait_ls_script.liq

################ DEBUT AJOUT POUR L'AUTODJ
 
########################### INIT PLAYLIST ##################################
 
ignore(run_process("python3 /home/radio-dragon/autoDJ/scripts/create_playlist.py"))
 
 
########################### REFRESH PLAYLIST EVERY NIGHT ##################################
 
exec_at(freq=1800., pred={ 23h00-23h50 },
  fun() -> ignore(run_process("python3 /home/radio-dragon/autoDJ/scripts/create_playlist.py"))
)
 
########################### TRANSITIONS ##################################
 
# a 3-seconds crossfade operator that skips the cutted track.
# Skipping avoids getting back in the middle of a music track after a live show,
# but it requires a weird implementation. See https://github.com/savonet/liquidsoap/issues/1548
def crossfade_3s(a,b)
    faded = add(normalize=false, [
        fade.in(duration=3., type="exp", b),
        amplify(mkfade(duration=3., start=1., stop=0., type="exp", a) ,a)
    ])
    add_timeout(10., { source.skip(a) ; -1.})
    faded
end
 
# Transition entre émission et playlist
def back_to_playlist(live, playlist) =
  # Cancel current track. This will also set the playlist
  # to play a new track.
  source.skip(playlist)
  sequence([live, playlist])
end
 
# Transition vers libretime
def to_libretime(playlist, live) =
  sequence([playlist,live])
end
 
 
########################### AUTODJ ##################################
 
autodj = playlist(reload_mode="watch", "/home/radio-dragon/autoDJ/playlist_autodj.txt",mode="normal")
 
# 780 = au moins 13 minutes de délai entre les jingles
# "delay" compte en secondes et c'est forcément un flottant d'ou le point obligatoire
jingles = delay(780., id="jingles",
    playlist.safe("/home/radio-dragon/Musique/JINGLES-BA-FOCUS/Jingles en COURS", mode="random", reload_mode="watch")
)
 
# à la fin de chaque track, va piocher un jingle s'il est dispo (après lecture, il n'est pas dispo)
autodj_avec_jingle = fallback([jingles, autodj], id="autodj_avec_jingle")
 
########################### PLAYLIST SECOURS ##################################
 
secours = mksafe(playlist("/home/radio-dragon/Musique/playlist_secours",reload_mode="watch"))
 
########################### COMBINING SOURCES ##################################
 
default = fallback(track_sensitive=false,transitions=[back_to_playlist,to_libretime],
	[autodj_avec_jingle,secours], id="default")
 
 
######################################################## FIN AJOUT POUR L'AUTODJ

Remarque : Les deux premières sections du script sont spéciales. Elles ont pour but d'exécuter la création (lors du lancement du script) ou la mise à jour (chaque jour entre 23h et 23h50) du fichier `playlist_autodj.txt`.

L'objectif est de générer (selon des règles précisées ici [LIEN À AJOUTER]) un fichier qui contient une playlist (liste de titres) qui dure au moins 24h.

La création du fichier playlist n'est pas faite directement dans le script liquidsoap. Elle est effectuée par un script écrit en python (pour des raisons de commodités, car le language liquidsoap est un peu particulier).

Le script liquidsoap lance donc le script python `create_playlist.py` qui lors de son exécution va générer le fichier `playlist_autodj.txt`.

Règles de rotation de la playlist

À DOCUMENTER