Documentation interne de Radio Dragon

Cette page est en lecture seule. Vous pouvez afficher le texte source, mais ne pourrez pas le modifier. Contactez votre administrateur si vous pensez qu'il s'agit d'une erreur.
====== Auto-DJ ======

L'auto-dj est le "logiciel" qui définit la diffusion de la musique pendant tous les "trous" de la grille (lorsqu'aucune émission, en direct ou pré-enregistrée, n'est diffusée).

Notre auto-dj est construit avec bout de script Liquidsoap qui est inséré au milieu du script Liquidsoap de libretime. Un deuxième script Liquidsoap  est nécessaire afin de récupérer en entrée un flux audio `http` provenant de Libretime pour le fournir en sortie sur la carte son de l'ordinateur (en direction de la table de mixage).

Ce deuxième script est nécessaire car Libretime est lancé en tant que "daemon system" (voir [[informatique:libretime:auto-dj#daemonscripts_qui_se_relancent_au_demarrage|section Daemon plus bas]]) et dans ce cas n'a pas pas les bons droits pour accéder correctement à la carte son. Le deuxième script liquidsoap est donc lancé lui en tant que "daemon user" (voir [[informatique:libretime:auto-dj#daemonscripts_qui_se_relancent_au_demarrage|section Daemon plus bas]]) afin de pouvoir envoyer le flux correctement sur la carte son. Cette configuration est un bidouillage qui pallie à un défaut de Libretime.

===== Localisation des fichiers =====

Les fichiers permettant de faire fonctionner l'auto-DJ se trouvent dans le dossier ''autoDJ'' dans ''/home/radiodragon''.

Le fichier ''playlist_autodj.txt'' est un simple fichier texte contenant une liste suffisantes de chemins vers des titres pour diffuser de la musique pendant au moins 24h. Cette playlist est recréée chaque jour selon des [[informatique:libretime:auto-dj#regles_de_rotation_de_la_playlist|règles de rotation précisées plus bas]].

Le sous-dossier ''scripts'' contient les scripts suivants :
  * ''radiodragon.liq'' : script liquidsoap secondaire
  * ''radiodragon-run.liq'' : configuration permettant de faire fonctionner ''radiodragon.liq'' en deamon **user**
  * ''create_playlist.py'' : script python permettant de générer une nouvelle playlist musicale tous les jours
===== Sript Liquidsoap dans Libretime =====

Le script liquidsoap inséré dans Libretime est documenté via des commentaires au sein même du script pour expliquer le fonctionnement de chaque section.

Le script en question est le fichier ''ls_script.liq'' situé dans ''/opt/libretime/lib/python3.8/site-packages/libretime_playout/liquidsoap/1.4/ls_script.liq''.

++++ Extrait inséré dans le script Liquidsoap - màj 10/01/2025 (cliquer pour afficher le script) |

<file liquidsoap extrait_ls_script.liq>

################ DEBUT AJOUT POUR L'AUTODJ

########################### INIT PLAYLIST ##################################

ignore(run_process("python3 /home/radio-dragon/autoDJ/scripts/create_playlist.py"))


########################### REFRESH PLAYLIST EVERY NIGHT ##################################

exec_at(freq=1800., pred={ 23h00-23h50 },
  fun() -> ignore(run_process("python3 /home/radio-dragon/autoDJ/scripts/create_playlist.py"))
)

########################### TRANSITIONS ##################################

# a 3-seconds crossfade operator that skips the cutted track.
# Skipping avoids getting back in the middle of a music track after a live show,
# but it requires a weird implementation. See https://github.com/savonet/liquidsoap/issues/1548
def crossfade_3s(a,b)
    faded = add(normalize=false, [
        fade.in(duration=3., type="exp", b),
        amplify(mkfade(duration=3., start=1., stop=0., type="exp", a) ,a)
    ])
    add_timeout(10., { source.skip(a) ; -1.})
    faded
end

# Transition entre émission et playlist
def back_to_playlist(live, playlist) =
  # Cancel current track. This will also set the playlist
  # to play a new track.
  source.skip(playlist)
  sequence([live, playlist])
end

# Transition vers libretime
def to_libretime(playlist, live) =
  sequence([playlist,live])
end


########################### AUTODJ ##################################

autodj = playlist(reload_mode="watch", "/home/radio-dragon/autoDJ/playlist_autodj.txt",mode="normal")

# 780 = au moins 13 minutes de délai entre les jingles
# "delay" compte en secondes et c'est forcément un flottant d'ou le point obligatoire
jingles = delay(780., id="jingles",
    playlist.safe("/home/radio-dragon/Musique/JINGLES-BA-FOCUS/Jingles en COURS", mode="random", reload_mode="watch")
)

# à la fin de chaque track, va piocher un jingle s'il est dispo (après lecture, il n'est pas dispo)
autodj_avec_jingle = fallback([jingles, autodj], id="autodj_avec_jingle")

########################### PLAYLIST SECOURS ##################################

secours = mksafe(playlist("/home/radio-dragon/Musique/playlist_secours",reload_mode="watch"))

########################### COMBINING SOURCES ##################################

default = fallback(track_sensitive=false,transitions=[back_to_playlist,to_libretime],
	[autodj_avec_jingle,secours], id="default")


######################################################## FIN AJOUT POUR L'AUTODJ 
  
</file>

++++

**Remarque :** Les deux premières sections du script sont spéciales. Elles ont pour but d'exécuter la création (lors du lancement du script) ou la mise à jour (chaque jour entre 23h et 23h50) du fichier ''playlist_autodj.txt''.

L'objectif est de générer ([[informatique:libretime:auto-dj#regles_de_rotation_de_la_playlist|selon des règles précisées ici]]) un fichier qui contient une playlist (liste de titres) qui dure au moins 24h.

La création du fichier playlist n'est pas faite directement dans le script liquidsoap. Elle est effectuée par un script écrit en //python// (pour des raisons de commodités, car le language //liquidsoap// est un peu particulier).

Le script liquidsoap lance donc le script python ''create_playlist.py'' qui lors de son exécution va générer le fichier ''playlist_autodj.txt''.

===== Deuxième script Liquidsoap =====

Le deuxième script liquidsoap est très simple, il prend un flux audio au format http (fournit par Libretime) pour le fournir à la carte son (pour l'envoyer à la table de mixage).

++++ Script liquidsoap secondaire - màj 10/01/2025 (cliquer pour afficher le script) |

<file liquidsoap radiodragon.liq>

#!/usr/bin/liquidsoap


########################### LIBRETIME ##################################

libretime = mksafe(input.http("http://192.168.1.105:8000/libretime",max=10.))

########################### OUTPUT ##################################

output.alsa(libretime)

#configuration possible de sortie sur serveur icecast
output.icecast(%opus,
  host="localhost",
  port=8000,
  mount="main.ogg",
  password= "aUukHdPiAkX2yjUTPTUO0PcNlKdkmsi4",
  libretime)
 
</file>

++++

===== Daemon : scripts qui fonctionnent en arrière-plan =====

Libretime est configuré comme un "daemon" system, ce qui veut dire que c'est un script qui fonctionne en arrière plan  et qui se lance automatiquement au démarrage de l'ordinateur, et qu'il est lancé **par le système** et non par un utilisateur.

Malheureusement un bug de Libretime nous empêche de sortir correctement le flux audio sur la carte son, justement car c'est un daemon **système**.

Nous utilisons donc un deuxième script liquidsoap afin de pallier à ce problème. Ce deuxième script est aussi un daemon (script qui fonctionne en arrière-plan) mais lancé par **l'utilisateur**, ce qui permet de fonctionner correctement avec la carte son. L'inconvénient est que ce script ne se relance pas tout seul au démarrage de l'ordinateur. Une solution est en cours de recherche pour corriger ce problème.

Afin que le script ''radiodragon.liq'' (voir plus haut) fonctionne comme un daemon, il faut créer et configurer correctement le script ''radiodragon-run.liq'' ci-dessous.

++++ Script pour faire un daemon liquidsoap - màj 10/01/2025 (cliquer pour afficher le script) |

<file liquidsoap radiodragon-run.liq>

#!/usr/bin/liquidsoap

set("log.file",true)
set("log.file.path","/home/radio-dragon/autoDJ/log/radiodragon-run.log")
set("init.daemon",true)
set("init.daemon.change_user",true)
set("init.daemon.change_user.group","radio-dragon")
set("init.daemon.change_user.user","radio-dragon")
set("init.daemon.pidfile",true)
set("init.daemon.pidfile.path","/home/radio-dragon/autoDJ/pid/radiodragon-run.pid")
set("init.daemon.pidfile.perms",0o640)
%include "/home/radio-dragon/autoDJ/scripts/radiodragon.liq"

</file>

++++

===== Règles de rotation de la playlist =====

À DOCUMENTER

===== Relancer l'auto-DJ en cas de problème =====

Listes de commandes a exécuter depuis un terminal afin de résoudre un problème d'exécution du script :
  * ''systemctl --user status radiodragon-liquidsoap.service''
    * permet de vérifier l'état du script liquidsoap secondaire
  * ''systemctl --user start radiodragon-liquidsoap.service''
    * permet de démarrer le daemon s'il est arrêté